Macros for SAS Application Developers
https://github.com/sasjs/core
Loading...
Searching...
No Matches
mp_rowhash.sas
Go to the documentation of this file.
1/**
2 @file
3 @brief Iterative row-level MD5 hash generator
4 @details Generates DATA step statements that compute a deterministic,
5 row-level MD5 hash using a Merkle-style construction. Each variable is
6 hashed independently and the resulting raw 16-byte digests are combined
7 iteratively. This avoids concatenating the per-variable hex digests into a
8 single SAS character expression, which overflows when datasets contain many
9 variables.
10
11 Temporary variables use five leading underscores.
12
13 This macro is called from inside a DATA step. The caller is responsible
14 for declaring the output hash column if it does not already exist on the
15 input dataset.
16
17 Variables are hashed in the order supplied. If a particular variable
18 needs to influence the hash first (for example the previous row hash in
19 `mp_hashdataset`, or business dates in Data Controller's bitemporal
20 loader) simply list it first in `cvars` or `nvars`.
21
22 @param [in] md5_col= Name of the output hash column.
23 @param [in] cvars= Space separated list of character variables to hash.
24 @param [in] nvars= Space separated list of numeric variables to hash.
25
26 <h4> SAS Macros </h4>
27 @li mf_getuniquename.sas
28
29 @version 9.3M5
30 @author Allan Bowe
31**/
32
33%macro mp_rowhash(
34 md5_col=
35 ,cvars=
36 ,nvars=
37 );
38
39 /* DATA step temp variables use five leading underscores. The names
40 are generated at macro invocation to avoid clashing with data columns. */
41 %local state digest pair numtext normal i chars nums;
42 %let state=%mf_getuniquename(prefix=_____state_);
43 %let digest=%mf_getuniquename(prefix=_____digest_);
44 %let pair=%mf_getuniquename(prefix=_____pair_);
45 %let numtext=%mf_getuniquename(prefix=_____numtext_);
46 %let normal=%mf_getuniquename(prefix=_____normal_);
47 %let i=%mf_getuniquename(prefix=_____i_);
48 %let chars=%mf_getuniquename(prefix=_____chars_);
49 %let nums=%mf_getuniquename(prefix=_____nums_);
50
51 length &state $16
52 &digest $16
53 &pair $32
54 &numtext $64
55 &normal &i 8;
56 if _n_=1 then call missing(&state,&digest,&pair,&numtext,&normal,&i);
57 drop &state &digest &pair &numtext &normal &i;
58
59 /* Versioned seed prevents confusion with other hashing schemes. */
60 &state = md5('DC HASH v2');
61
62 %if %length(&cvars)>0 %then %do;
63 array &chars{*} $ &cvars;
64 do &i = 1 to dim(&chars);
65 /* Leading blanks are retained. */
66 &digest = md5(trimn(&chars[&i]));
67 substr(&pair, 1, 16) = &state;
68 substr(&pair, 17, 16) = &digest;
69 &state = md5(&pair);
70 end;
71 %end;
72
73 %if %length(&nvars)>0 %then %do;
74 array &nums{*} &nvars;
75 do &i = 1 to dim(&nums);
76 /*
77 multiply-by-one for consistent cross-system precision.
78 Ignore null to protect SAS special missing values.
79 Cannot use IFN() as it evaluates both sides
80 */
81 if missing(&nums[&i]) then &normal = &nums[&i];
82 else &normal = &nums[&i] * 1;
83 &numtext = put(&normal, binary64.);
84 &digest = md5(trim(&numtext));
85 substr(&pair, 1, 16) = &state;
86 substr(&pair, 17, 16) = &digest;
87 &state = md5(&pair);
88 end;
89 %end;
90
91 &md5_col = put(&state, $hex32.);
92
93%mend mp_rowhash;